Права, групи та префікси

Оператор (op) — це «може все», включно із зупинкою сервера. Не видавайте його помічникам чи донатерам. Для правильної ієрархії потрібен LuckPerms — його розуміє майже кожен плагін.

Встановлення

Перейдіть у розділ «Плагіни та моди» → знайдіть LuckPerms → «Встановити» → перезапустіть сервер. Щоб перевірити, виконайте /plugins у «Консолі».

Групи

Стандартна схема: default → vip → moderator → admin, де кожна група успадковує попередню.

/lp creategroup vip
/lp group vip parent add default
/lp user Nick parent add vip
/lp user Nick parent remove vip

Групу default нові гравці отримують автоматично — у ній базові можливості: /spawn, /home, /msg.

Права

/lp group vip permission set essentials.fly true
/lp group vip permission unset essentials.fly
/lp user Nick permission set worldedit.wand true

Право * дорівнює правам оператора — видавайте його лише тим, кому довіряєте весь сервер.

Префікси в чаті

/lp group vip meta setprefix 100 "&a[VIP] "
/lp group admin meta setprefix 200 "&c[Admin] "

Число — це пріоритет: якщо гравець перебуває в кількох групах, показується префікс із більшою вагою. Щоб префікс справді з'явився в чаті, потрібен плагін, який його відображає — EssentialsX Chat або будь-який чат-плагін (Базові команди).

Вебредактор

Команда /lp editor дає посилання на редактор у браузері: ви редагуєте групи, права та успадкування мишкою, а кнопка «Зберегти» застосовує все на сервері. Для налаштування з нуля це в рази швидше за команди.

Тимчасові права

Донат на місяць не потрібно знімати вручну:

/lp user Nick parent addtemp vip 30d

Чого робити не варто

• Тримати більше ніж 4–5 груп «про всяк випадок»: розбиратися з ними потім доведеться вам.
• Видавати op замість групи. op ігнорує всі обмеження LuckPerms.
• Роздавати worldedit.* будь-кому, крім себе — одна команда може знищити половину мапи (дивіться Відкат гриферства).

Про те, як закрити небезпечні команди навіть для операторів, дивіться Безпека адмін-панелі.